版权归作者所有，如有转发，请注明文章出处：https://cyrus-studio.github.io/blog/

编译环境准备

1. Windows下启用开发者模式，因为需要 symbolic link 支持 image.png

image.png

2. 安装 python3.8+，并配置PATH环境变量

# 查看python版本信息
py --version
# 查看所有已安装的 Python 解释器路径
py -0p

3. git 启用 symbolic links

# 启用 symbolic links
git config --global core.symlinks true
# 查看 git 配置
git config --global --list

4. 安装 Android Studio ，设置环境变量 ANDROID_HOME 为 Android SDK 文件夹的路径。该路径可以在 Android Studio 的设置中找到。

5. 下载 Magisk 源码

# 下载 Magisk 源码
git clone --recurse-submodules https://github.com/topjohnwu/Magisk.git

# 如果子模块克隆失败，可以手动克隆这些子模块。进入对应的子模块路径，然后执行以下命令
git submodule update --init --recursive

6. 运行 ./build.py ndk，下载并安装 NDK。

py .\build.py ndk

编译MagiskBoot

# 编译 native 模块，包括 magiskinit magisk magiskboot magiskpolicy
py .\build.py native

# 编译所有模块
py .\build.py all

编译成功后，在 Magisk\native\out\arm64-v8a 目录下可以看到 magiskboot 文件已经生成 image.png

使用 magiskboot 解包&打包内核

# 解包 boot.img
./magiskboot unpack boot.img

# 重新打包 img，得到一个 new-boot.img
./magiskboot repack boot.img

在Windows下使用magiskboot

在 magiskboot_build 上下载 magiskboot-e159716-release-windows-mingw-w64-msvcrt-i686-standalone.zip 并解压到 D:\App\magiskboot 目录下

image.png

新建 unpack.bat，扩展 magiskboot 使其可指定解压目录

@echo off
:: 检查是否提供了 IMG_PATH 参数
if "%~1"=="" (
    echo 请提供boot.img文件的路径作为参数！
    exit /b 1
)

:: 获取当前批处理文件所在的目录
set "SCRIPT_DIR=%~dp0"

:: 将相对路径转换为绝对路径
for %%I in ("%~1") do (
    set "IMG_PATH=%%~fI"
    set "OUTPUT_DIR=%%~dpI%%~nI"
)

:: 创建输出目录（如果不存在）
if not exist "%OUTPUT_DIR%" (
    mkdir "%OUTPUT_DIR%"
)

:: 解包 boot.img 到输出目录
cd "%OUTPUT_DIR%"
"%SCRIPT_DIR%magiskboot" unpack "%IMG_PATH%"

echo 解包完成，文件已解包到 "%OUTPUT_DIR%" 目录中。

新建 repack.bat，根据指定解压目录重新打包 img，并把 new-boot.img 存放在解压目录下

@echo off
:: 检查是否提供了解包目录路径作为参数
if "%~1"=="" (
    echo 请提供解包目录的路径作为参数！
    exit /b 1
)

:: 获取当前批处理文件所在的目录
set "SCRIPT_DIR=%~dp0"

:: 将相对路径转换为绝对路径并获取解包目录名称
for %%I in ("%~1\.") do (
    set "UNPACK_DIR=%%~fI"
    set "UNPACK_NAME=%%~nxI"
)

:: 检查是否成功获取目录名称
if "%UNPACK_NAME%"=="" (
    echo 无法获取解包目录的名称！
    exit /b 1
)

:: 获取 UNPACK_DIR 的父目录路径
for %%I in ("%UNPACK_DIR%\..") do (
    set "PARENT_DIR=%%~fI"
)

:: 设置新的 BOOT_IMG 路径，位于 UNPACK_DIR 的父目录
set "BOOT_IMG=%PARENT_DIR%\%UNPACK_NAME%.img"

:: 切换到解包目录
cd "%UNPACK_DIR%"

:: 打包回 boot.img
"%SCRIPT_DIR%magiskboot" repack "%BOOT_IMG%"

echo 打包完成，新的 "%BOOT_IMG%" 已生成并存放在 "%UNPACK_DIR%"。

将 magiskboot 解压路径添加到系统 Path 环境变量 image.png

# 解包 boot.img
unpack .\boot.img
# 重新打包 img，得到一个 new-boot.img 在 boot 目录下
repack .\boot\

源码地址：https://github.com/CYRUS-STUDIO/MagiskBootWindows

参考： Magisk V26.1 编译 在 macOS/Windows/Linux 上使用 magiskboot Magisk Building and Development